verilog键盘扫描程序之debug
0赞上次的日志《经典的verilog键盘扫描程序》承蒙厚爱，但是我发现那个经典程序还是存在一点点小bug，且听我慢慢道来。
先放上仿真波形来说明一下问题吧：
仿真说明：由于20ms检测一次按键值对于仿真来说太长了，所以只假定16个主时钟周期就做一次 检测（也就是cnt[3]的下降沿锁存键值）。
图1，sw1_n被按下（拉底）大约5个时钟周期（<16）,而此时与其相应的led_d5却改变状态了。说明的 问题是，大多数时候按键消抖其实是到不了20ms的。
其实这个小bug通常在下载后，测试键盘是不会有什么感觉的。但是问题是，如果真的出现那种 抖动在20ms以内（甚至远小于20ms）的外部干扰存在时， 这个bug就不可忽视了。
因此，在原程序的基础上，做了如下的改进。其思想是在每个主时钟（50MHz）周期里都进行一次按 键检测，如果前后两次键值改变了，说明有可能键盘被按下了，此时，在下一个时钟周期将复位20ms计数值，然后20ms后重新锁存键值，其它 的和原程序基本相同，这样就达到了真正意义上的20ms消抖。
重新修改代码后的仿真波形如下：
图2，可以看到此时在不满16个时钟周期的键值变化是不会然led做出变化的。
图3，按键sw3_n的按下时间明显超过了16个时钟周期，那么在cnt重新记到16个时钟周期后，led_d4就做出了改变。
重新修改后的代码如下：
//当三个独立按键的某一 个被按下后，相应的LED被点亮；再次按下后，LED熄灭，按键控制LED亮灭
`timescale 1ns/1ns
module keyscan(
clk,
rst_n,
sw1_n,
sw2_n,
sw3_n,
//output
led_d3,
led_d4,
led_d5
);
input clk; //主时钟信号，48MHz
input rst_n; //复位信号，低有效
input sw1_n,sw2_n,sw3_n; //三个独立按键，低表示按下
output led_d3,led_d4,led_d5; //发光二极管，分别由按键控制
// ---------------------------------------------------------------------------
reg [2:0] key_rst;
always @(posedge clk or negedge rst_n)
if (!rst_n)
key_rst <= 3'b111;
else
key_rst <= {sw3_n,sw2_n,sw1_n};
reg [2:0] key_rst_r; //每个时钟周期的上升沿将low_sw信号锁存到low_sw_r中
always @ ( posedge clk or negedge rst_n )
if (!rst_n)
key_rst_r <= 3'b111;
else
key_rst_r <= key_rst;
//当寄存器key_rst由1变为0时，led_an的值变为高，维持一个时钟周期
wire [2:0] key_an = key_rst_r & ( ~key_rst);
// ---------------------------------------------------------------------------
reg [19:0] cnt; //计数寄存器
always @ (posedge clk or negedge rst_n)
if (!rst_n) //异步复位
cnt <= 20'd0;
else if(key_an)
cnt <=20'd0;
else
cnt <= cnt + 1'b1;
reg [2:0] low_sw;
always @(posedge clk or negedge rst_n)
if (!rst_n)
low_sw <= 3'b111;
else if (cnt == 20'hfffff) //满20ms，将按键值锁存到寄存器low_sw中 cnt == 20'hfffff
low_sw <= {sw3_n,sw2_n,sw1_n};
// ---------------------------------------------------------------------------
reg [2:0] low_sw_r; //每个时钟周期的上升沿将low_sw信号锁存到low_sw_r中
always @ ( posedge clk or negedge rst_n )
if (!rst_n)
low_sw_r <= 3'b111;
else
low_sw_r <= low_sw;
//当寄存器low_sw由1变为0时，led_ctrl的值变为高，维持一个时钟周期
wire [2:0] led_ctrl = low_sw_r[2:0] & ( ~low_sw[2:0]);
reg d1;
reg d2;
reg d3;
always @ (posedge clk or negedge rst_n)
if (!rst_n)
begin
d1 <= 1'b0;
d2 <= 1'b0;
d3 <= 1'b0;
end
else
begin //某个按键值变化时，LED将 做亮灭翻转
if ( led_ctrl[0] ) d1 <= ~d1;
if ( led_ctrl[1] ) d2 <= ~d2;
if ( led_ctrl[2] ) d3 <= ~d3;
end
assign led_d5 = d1 ? 1'b1 : 1'b0; //LED翻转输出
assign led_d3 = d2 ? 1'b1 : 1'b0;
assign led_d4 = d3 ? 1'b1 : 1'b0;
endmodule
